Converting Numbers To Shorter/Easier to Convey Strings

Thumbnails Using ASPImage

by johna | October 25, 2007 | Classic ASP Web Development

This script creates thumbnails for images using Server Object's ASPImage (see www.serverobjects.com).

You specify the image path and filename and the height and width required and this script will return the resized image.

The original aspect ratio of the image will allways be retained and whitespace will be added if neccessary to ensure that the dimensions are as requested. If there is any whitespace then you can choose to have the image centred or left/right aligned or top/bottom aligned.

Call the script using the following syntax:

<img src="thumbnail.asp?src=image.jpg&align=center&valign=center&height=100&width=75">

Where src is the path and filename (URL Encoded), align is the horizontal alignment (left, center or right, default is left), valign is the vertical alignment (top, center or bottom, default is top), height is the height in pixels, and width is the width in pixels.

thumbnail.asp

<%
'Get image filename
strImage = Request("src")
'Get request characteristics
If IsNumeric(Request("width")) Then
	intWidth = CInt(Request("width"))
Else
	intWidth = 0
End If
If intWidth = 0 Then intWidth = 100 'default size is 100x100
If IsNumeric(Request("height")) Then
	intHeight = CInt(Request("height"))
Else
	intHeight= 0
End If
If intHeight= 0 Then intHeight = intWidth
strAlign = LCase(Request("align"))
If strAlign = "" Then strAlign = "left" 'default align is left
strVAlign = LCase(Request("valign"))
If strVAlign = "" Then strVAlign = "top" 'default align is top
Set Image = Server.CreateObject("AspImage.Image")
Image.PadSize = 0
Image.LoadImage(Server.MapPath(strImage))
Image.ImageFormat = 1
Response.ContentType = "image/jpeg"
'Set your image quality here
Image.JPEGQuality = 30
intXSize = Image.MaxX
intYSize = Image.MaxY
If (intWidth / intXSize) > (intHeight / intYSize) Then
	intXSize = Int( (intHeight / Image.MaxY) * Image.MaxX )
	intYSize = intHeight
	Image.ResizeR intXSize, intYSize
	If strAlign = "center" Then
		intPadding = Int((intWidth - Image.MaxX) / 2)
		Image.CropImage -(intPadding), 1, Image.MaxX + intPadding, Image.MaxY
	ElseIf strAlign = "right" Then
		intPadding = Int(intWidth - Image.MaxX)
		Image.CropImage -(intPadding), 1, Image.MaxX + intPadding, Image.MaxY
	End If
	Image.MaxX = intWidth
Else
	intXSize = intWidth
	intYSize = (intWidth / Image.MaxX) * Image.MaxY
	Image.ResizeR intXSize, intYSize
	If strVAlign = "center" Then
		intPadding = Int((intHeight - Image.MaxY) / 2)
		Image.CropImage 1, -(intPadding), Image.MaxX, Image.MaxY + intPadding
	ElseIf strVAlign = "bottom" Then
		intPadding = Int(intHeight - Image.MaxY)
		Image.CropImage 1, -(intPadding), Image.MaxX, Image.MaxY + intPadding
	End If
	Image.MaxY = intHeight
End If
Response.BinaryWrite Image.Image
set Image = nothing
%>

Web Development Retro Computing

Converting dBase IV programs to run in the browser

by johna | September 13, 2024

Some pointless entertainment trying to get some old dBase programs running in the browser.

Web Development

How to set up a debugging using the Turnkey Linux LAMP stack and VS Code

by johna | December 19, 2023

The second part in my guide to setting up a website and database using the Turnkey Linux LAMP stack.

Website Hosting Web Development

How to set up a website and database using the Turnkey Linux LAMP stack

by johna | November 18, 2023

If you need to host your own website for the purposes of web development, Turnkey Linux LAMP Stack is an easy to install all-in-one solution that you can set up on a spare computer or a VM (Virtual Machine).

Comments

by Colin | October 29, 2007

I cant seem to get this working i just get the "no image" red box.. any suggestions??

by John Avis | October 29, 2007

I just re-tested it and all seems fine. You MUST have ASPImage installed on the server and it must be version 2.x. Also, this script will not tolerate a missing file. And I should point out that the file name should be relative to the folder containing thumbnail.asp (you can change these things if you like).

Thumbnails Using ASPImage

Related Posts

Converting dBase IV programs to run in the browser

How to set up a debugging using the Turnkey Linux LAMP stack and VS Code

How to set up a website and database using the Turnkey Linux LAMP stack

Comments

About

Subscribe